牧師巨集整理

整合技能

---

堅韌禱言&真言術:韌
#showtooltip 堅韌禱言
/cast [btn:2] [mod] 堅韌禱言; 真言術:韌

如果以右鍵點擊、或是按著控制鍵（ctrl、alt、shift）時，使用堅韌禱言；否則使用真言術:韌。

---

暗影防護禱言&暗影防護
#showtooltip 暗影防護禱言
/cast [btn:2] [mod] 暗影防護禱言; 暗影防護

---

精神禱言&神聖之靈
#showtooltip 精神禱言
/cast [btn:2] [mod] 精神禱言; 神聖之靈

---

群體驅魔&驅散魔法
#showtooltip 群體驅魔
/cast [btn:2] [mod] 群體驅魔; 驅散魔法

---

心靈專注
#showtooltip 強效治療術
/cast [mod] 心靈專注
/cast 強效治療術

使用強效治療術。如果按著控制鍵（ctrl、alt、shift）時，則先使用心靈專注，再使用強效治療術。

智慧施法

---

強效治療術
#showtooltip
/cast [@player,button:2] [@mouseover,help] [help] [@targettarget,help] [] 強效治療術

若以右鍵點擊，則對自己本身使用；否則對一個滑鼠所指示的友善對象、友善目標、或該目標所注視的友善目標使用。

善用mouseover的功能，可以專注在某個目標身上時，還能快速地去照顧其他隊友。

#showtooltip
/cast [mod,spec:1] 心靈專注
/cast [@player,button:2] [@mouseover,help] [help] [@targettarget,help] [] 強效治療術

承上，追加若按著控制鍵（ctrl、alt、shift），而且是在第1天賦下時，則先使用心靈專注，再使用強效治療術。

---

真言術:盾
#showtooltip
/cast [@player,btn:2] [@mouseover,help] [help] [@targettarget,help] [] 真言術:盾

---

束縛治療
#showtooltip
/cast [@mouseover,help] [help] [@targettarget,help] [] 束縛治療

對一個滑鼠所指示的友善對象、友善目標、或該目標所注視的友善目標使用束縛治療。

---

懺悟
#showtooltip [@mouseover,help] [] 懺悟
/cast [@player,btn:2] [@mouseover,help] [help] 懺悟

若以右鍵點擊，則對自己本身使用懺悟；否則對一個滑鼠所指示的友善對象、或是對友善目標使用懺悟。
此巨集會限定懺悟僅能用於治療。

#showtooltip
/cast [@player,btn:2] [@mouseover,exists] [] 懺悟

若以右鍵點擊，則對自己本身使用懺悟；否則對一個滑鼠所指示的對象、或是對目標使用懺悟。
此巨集不限定懺悟的對象之狀態，可用於攻擊也可用於治療。

#showtooltip
/stopmacro [noexists]
/cast [nohelp,btn:2] [nohelp,mod] [@targettarget,nohelp,btn:2] [@targettarget,nohelp,mod] [help] [@targettarget,help] [] 懺悟

對一個友善目標、或該目標所注視的友善目標使用懺悟；如果以右鍵點擊或按著控制鍵（ctrl、alt、shift）時，則改為對非友善目標、或友善目標所注視的非友善目標使用懺悟。

---

驅散魔法
#showtooltip
/cast [@player,btn:2] [@mouseover,exists,nodead] [] 驅散魔法

驅散魔法對敵對友皆有效，故不需要敵我辨識功能。

#showtooltip
/cast [mod] [btn:2] 群體驅魔; [@mouseover,exists,nodead] [] 驅散魔法

再與群體驅魔進行整合。

---

沉默
#showtooltip
/stopcasting
/cast [nohelp] [@targettarget,exists,nohelp] [] 沉默

立刻中斷目前的法術，並對非友善目標、或友善目標的非友善目標使用沉默。

---

精神鞭笞
#showtooltip
/stopmacro [channeling:精神鞭笞]
/cast 精神鞭笞

避免在連續使用引導法術時打斷引導。

focus控場

---

束縛不死生物
#showtooltip [@focus] [] 束縛不死生物
/focus [btn:2] [@focus,dead] [@focus,noexists]
/cast [@focus] 束縛不死生物

如果以右鍵點擊，則直接對focus對象使用控場法術。當focus對象不存在、或已經死亡的話，亦或是沒有使用右鍵，則會將目標設為新的focus之後，再使用控場法術。

透過這樣的巨集，只要在第一次進行控場時注視該目標，再次控場時，不論目標為誰，只要按下右鍵即可進行控場。

技能連鎖

---

心靈震爆&精神鞭笞
#showtooltip
/stopmacro [channeling:精神鞭笞]
/castsequence reset=3/alt/shift/ctrl 心靈震爆, 精神鞭笞, 精神鞭笞

依序使用心靈震爆以及兩次精神鞭笞。如果使用此巨集後3秒內沒有再度使用，或按著控制鍵（ctrl、alt、shift）時，重置此巨集。

復活

---

復活術&隨機發言
#showtooltip
/cast 復活術
/stopmacro [nohelp] [nodead]
/script s={"台詞一","台詞二","台詞三"};
/script SendChatMessage(s[random(#s)], "SAY");

修改台詞、增刪台詞時須注意，每段台詞的前後都要有雙引號，台詞與台詞之間以逗號區隔。%t可用來代表目標的名稱。總字數不能超過256個字。